연관된 두 집단의 비교 - Paired t-test 와 Wilcoxon Signed Rank sum Test

연관된 두 집단의 비교 - Paired t-test 와 Wilcoxon Signed Rank sum Test

 

독립이 아닌 표본으로 부터 어떤 처리의 전(pre)과 후(post)의 측정치가 있거나, 동일한 개체에 서로 다른 처리를 한후 그 효과를 비교할때 사용되는 모수적 방법으로는 Paired t-est 가 있고, 비모수적 방법으로는 Wilcoxon signed rank sum test 가 있습니다.

---

1. Paired t-test

- Normality Assumption 과 등분산 가정은 indepndent t-test 와 동일합니다.

 

Ex. 어떤 약물을 투여 전/후의 Total cholesterol 의 차이가 있는지 테스트해 보겠습니다.

 

<SAS Code>

data test_data;
    input ID pre_tchl post_tchl;
    datalines;
1 201 200 
2 231 236
3 221 216
4 260 233
5 228 224
6 237 216
7 326 296
8 235 195
9 240 207
10 267 247
11 284 210
12 201 209
;
run;

/*perform paired samples t-test*/
proc ttest data=test_data;
    paired pre_tchl*post_tchl;
run;

 

<SAS Output>

paired t-test 결과

Ho 가 pre, post 의 tchl 가 equal이므로 p-value=0.0117 로 기각하게 되어, 결과적으로 약물 전후 Total cholesterol 의 차이는 유의하다고 할 수 있습니다.

---

2. Wilcoxon Signed Rank Sum Test

Ex. 어떤 treatment 전/후의 타이어 압력의 차이가 있는지 테스트해 보겠습니다.

 

<SAS Code>

/*create dataset*/

data test_data;
    input ID treat no_treat;
    datalines;
1 20 24
2 23 25
3 21 21
4 25 22
5 18 23
6 17 18
7 18 17
8 24 28
9 20 24
10 24 27
11 23 21
12 19 23
;
run;

/*create data with difference according to treatmemt*/
data test_data;
    set test_data;
    diff=treat-no_treat;
run;

/*perform Wilcoxon Signed Rank Test*/
proc univariate data=test_data;
    var diff;
run;

 

<SAS Output>

Univariate 결과 중 위치모수 검정(Testing for Location) 부분의 결과 중 3번째에 있는 Pr >= |S| 의 결과를 보면 된다. 즉, p-value=0.0469 로 treatment 전후 타이어 압력의 차이가 유의하게 있다고 결론을 내릴 수 있습니다.

 

 Univariate 는 총 3개의 위치모수 검정결과를 보여 줍니다. ( Ho : Mu=0 (차이가 없다))

 

- Student-t 로 Noramlity 가정에 이 경우는 위배되므로 무시합니다.

- Sign test 의 결과입니다. 

- Wilcoxn Signed Rank sum test 결과입니다.